'Below is sample code for calculating field values, from the "Getting to Know
'ArcObjects" book, Chapter 20, Exercise 20B. This code adds a field called
'Stand_Value to an attribute table that has the fields ValuePerMeter and 
'Shape_Area, and populates Stand_Value with the product of the values in
'the other two fields. 
 
Private Sub LeaseValue_Click()
    Dim pMxDoc As IMxDocument
    Set pMxDoc = ThisDocument
    
    Dim pFLayer As IFeatureLayer
    Set pFLayer = pMxDoc.ContextItem
    
    Dim pFClass As IFeatureClass
    Set pFClass = pFLayer.FeatureClass
    
    Dim pFields As IFields
    Set pFields = pFClass.Fields
    
    Dim intPosStandValue As Integer
    intPosStandValue = pFields.FindField("StandValue")
    
    If intPosStandValue = -1 Then
        
        Dim pFieldEdit As IFieldEdit
        Set pFieldEdit = New Field
        
        pFieldEdit.Name = "StandValue"
        pFieldEdit.Type = esriFieldTypeDouble
        pFClass.AddField pFieldEdit
    
    intPosStandValue = pFields.FindField("StandValue")
    End If
    
    Dim intPosValuePerMeter As Integer
    intPosValuePerMeter = pFields.FindField("ValuePerMeter")
    
    Dim intPosShape_Area As Integer
    intPosShape_Area = pFields.FindField("Shape_Area")
    
    Dim pFCursor As IFeatureCursor
    Set pFCursor = pFClass.Update(Nothing, True)
    
    Dim pFeature As IFeature
    Set pFeature = pFCursor.NextFeature
        
    Do Until pFeature Is Nothing
        pFeature.Value(intPosStandValue) = _
            pFeature.Value(intPosValuePerMeter) * _
            pFeature.Value(intPosShape_Area)
        pFCursor.UpdateFeature pFeature
        Set pFeature = pFCursor.NextFeature
    Loop