Public Shared Sub ChangeLineColor()
        Dim pLayer As ILayer
        Dim pDSet As IDataset

        pLayer = My.ArcMap.Document.FocusMap.Layer(0)
        pDSet = TryCast(pLayer, IDataset) 'aka QI

        MsgBox(pLayer.Name)
        MsgBox(pDSet.Workspace.PathName)

        'create and set color
        Dim pColor As New RgbColor
        pColor.RGB = RGB(255, 0, 0)

        'create and set symbol
        Dim pSymbol As ILineSymbol
        pSymbol = New SimpleLineSymbol
        pSymbol.Color = pColor

        'create and set renderer
        Dim pRenderer As ISimpleRenderer = New SimpleRenderer
        pRenderer.Symbol = pSymbol

        Dim pMxDoc As IMxDocument
        Dim pGFLayer As IGeoFeatureLayer
        pMxDoc = My.ArcMap.Document
        If TypeOf (pLayer) Is IFeatureLayer Then
            pGFLayer = pLayer 'implicit casting
            pGFLayer.Renderer = pRenderer
            pMxDoc.UpdateContents() 'update TOC
            pMxDoc.ActivatedView.Refresh() 'update view
        Else
            MsgBox("Not a feature layer")
        End If
        'clean up
        pRenderer = Nothing
        pSymbol = Nothing
        pColor = Nothing
        GC.Collect()
        GC.WaitForPendingFinalizers()
    End Sub

    Public Shared Sub ChangeLineStyle()
        Dim pMxDoc As IMxDocument = My.ArcMap.Document
        Dim pLayer As ILayer = pMxDoc.FocusMap.Layer(0)

        Dim pStyleG As IStyleGallery = pMxDoc.StyleGallery
        Dim pEnumStyleG As IEnumStyleGalleryItem
        pEnumStyleG = pStyleG.Items( _
                    "Line Symbols", "ESRI.style", "Dashed")
        'Items Arguments: Class Name, StyleSet, and Category

        pEnumStyleG.Reset()
        Dim pLineSym As ILineSymbol
        Dim pStyleItem As IStyleGalleryItem = pEnumStyleG.Next

        Do Until pStyleItem Is Nothing
            MsgBox(pStyleItem.Name)
            If pStyleItem.Name = "Dashed 4:4" Then
                pLineSym = pStyleItem.Item
                Exit Do
            End If
            pStyleItem = pEnumStyleG.Next
        Loop

        'create and set renderer
        If pLineSym IsNot Nothing Then
            Dim pRenderer As ISimpleRenderer = New SimpleRenderer
            pRenderer.Symbol = pLineSym

            Dim pGFLayer As IGeoFeatureLayer
            pGFLayer = pLayer 'implicit casting
            pGFLayer.Renderer = pRenderer
            pMxDoc.UpdateContents() 'update TOC
            pMxDoc.ActivatedView.Refresh() 'update view
        End If
        'clean up
        GC.Collect()
        GC.WaitForPendingFinalizers()
    End Sub

    Public Shared Sub DisplayRaster()
        Dim pMxDoc As IMxDocument = My.ArcMap.Document
        Dim pLayer As ILayer = pMxDoc.FocusMap.Layer(0)
        Dim pRLayer As IRasterLayer = pLayer 'casting

        Dim pStyleG As IStyleGallery = pMxDoc.StyleGallery
        Dim pEnumStyleG As IEnumStyleGalleryItem
        pEnumStyleG = pStyleG.Items( _
                    "Color Ramps", "ESRI.style", "Default Ramps")
        pEnumStyleG.Reset()

        Dim pColorRamp As IColorRamp = New PresetColorRamp
        Dim pStyleItem As IStyleGalleryItem = pEnumStyleG.Next

        Do Until pStyleItem Is Nothing
            If pStyleItem.Name = "Elevation #2" Then
                pColorRamp = pStyleItem.Item
                Exit Do
            End If
            pStyleItem = pEnumStyleG.Next
        Loop

        'create the colorramp
        With pColorRamp
            .Size = 5 'an arbitrary number
            .CreateRamp(True)
        End With

        'create raster renderer
        Dim pUVRenderer As IRasterUniqueValueRenderer = _
                New RasterUniqueValueRenderer
        Dim pRasRenderer As IRasterRenderer
        pRasRenderer = TryCast(pUVRenderer, IRasterRenderer) 'casting

        pRasRenderer.Raster = pRLayer.Raster
        pRasRenderer.Update()

        Dim pFSymbol As ISimpleFillSymbol
        pFSymbol = New SimpleFillSymbol

        For i As Integer = 0 To 4
            pUVRenderer.AddValue(0, i, i + 1)
            pUVRenderer.Label(0, i) = i + 1
            pFSymbol.Color = pColorRamp.Color(i)
            pUVRenderer.Symbol(0, i) = pFSymbol
        Next

        pRasRenderer.Update()

        'Update the renderer with new settings and plug into layer
        pRLayer.Renderer = pRasRenderer
        pMxDoc.UpdateContents() 'update TOC
        pMxDoc.ActivatedView.Refresh() 'update view

        'clean up
        GC.Collect()
        GC.WaitForPendingFinalizers()
    End Sub